3.15.3 Rprinter
DNF95774
Rprinter wird unter DOS und Windows 3.1x mit NetWare 3.x benutzt, um lokale Drucker auch im Netzwerk ansprechen zu können. Dazu wird Rprinter an der Arbeitsstation (als TSR) gestartet und signalisiert dem Print Server: Hier steht der Drucker Nummer x.
RPRINTER
[-P]
Die neueren Rprinter Versionen (ab Version 1.26) kann man mit dem Parameter -P im Pollingmode betreiben. Damit sind viele früheren Probleme auch unter Windows beseitigt.
Rprinter hat aber weiterhin das Problem, daß nach einem Neustart der WS die erneute Verbindung zum Printserver nicht wieder aufgebaut werden kann, bis der Pserver bemerkt hat, daß der Rprinter nicht mehr im Netz ist und die Verbindung wieder freigibt. Solange meldet dieser "Drucker schon belegt".
Dies kann man aber sehr einfach lösen, indem man den Errorlevel von Rprinter abfragt und eine Schleife bzw. eine Meldung anzeigt.
@echo off
rem -- Rprinter-Installation (Batch von Adreas Beutling)
if not "%2"=="" goto nohelp
echo Aufruf: rprint druckserver druckernummer
echo Default: rprint drucker 0
:nohelp
rem -- Variablen einrichten
set rp=
set ps=%1
set pn=%2
if "%ps%"=="" set ps=drucker
if "%pn%"=="" set pn=0
goto install
:wait
rem hier kann man ein bißchen warten... z.B.: Wait 5
rem oder Choice dazu benutzen
:install
rem -- Rprinter entfernen
rprinter %ps% %pn% /r
rem -- Rprinter installieren
rem (/p für Polling Mode)
rprinter %ps% %pn% /p
rem -- Schleifenzähler abfragen (hier für 10 Durchlaeufe)
if "%rp%"=="xxxxxxxxxx" goto ende
rem -- Schleifenzaehler erhöhen
set rp=%rp%x
rem -- Rprinter-Installation erfolgreich?
if errorlevel 1 goto wait
rem -- Status anzeigen
rprinter %ps% %pn% /s
:ende
rem -- Variablen löschen
set rp=
set ps=
set pn=
Die Prozedur kann (je nach Anzahl der Durchläufe) länger laufen, bricht den Vorgang dann aber ab, wenn ein anderer Rechner diesen Drucker "angemeldet" hat.
Alternativ gibt es auch externe Printerserver, entweder intern für bestimmte (Laser-) Drucker oder als externes Modell für beliebige parallele oder serielle Drucker. Diese Printserver belegen je nach Einstellung keine oder eine Userconnection und machen erfahrungsgemäß die wenigsten Probleme.
Hinweis: Ab Netware 4.x heisst dieses Programm NPrinter und ist auch für verschiedene Windows-Version verfügbar. (siehe die entsprechenden Tipps)
| 